Private Sub Form_Load()
Dim objApp As SolidEdgeFramework.Application
Dim objDoc As SolidEdgePart.PartDocument
Dim objBaseProfile As SolidEdgePart.Profile
Dim objBaseProfileArray(1 To 2) As SolidEdgePart.Profile
Dim objBaseModel As SolidEdgePart.Model
Dim objProfile As SolidEdgePart.Profile
Dim objLine As SolidEdgeFrameworkSupport.Line2d
Dim objRefAxis As SolidEdgePart.RefAxis
Dim objCrossSection As SolidEdgeFrameworkSupport.Circle2d
Dim objCSArray(1 To 2) As SolidEdgePart.Profile
Dim objHelixCutout As SolidEdgePart.HelixCutout
Dim objHCParent As SolidEdgePart.Model
Dim lngStatus As Long
' Report errors
Const PI = 3.14159265358979
' Create/get the application with specific settings
On Error Resume Next
Set objApp = GetObject(, "SolidEdge.Application")
If Err Then
Err.Clear
Set objApp = CreateObject("SolidEdge.Application")
Set objDoc = objApp.Documents.Add("SolidEdge.PartDocument")
objApp.Visible = True
Else
Set objDoc = objApp.ActiveDocument
End If
' *** creating the base feature
' creating a circular profile for the base extruded protrusion feature and validating it
Set objBaseProfile = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(1))
Call objBaseProfile.Circles2d.AddByCenterRadius(x:=0, y:=0, Radius:=0.05)
lngStatus = objBaseProfile.End(ValidationCriteria:=igProfileClosed)
If (lngStatus <> 0) Then
MsgBox "Profile for the base feature is not closed"
Exit Sub
End If
' creating the base extruded protrusion feature
Set objBaseProfileArray(1) = objBaseProfile
Set objBaseModel = objDoc.Models.AddFiniteExtrudedProtrusion(NumberOfProfiles:=1, _
ProfileArray:=objBaseProfileArray, ProfilePlaneSide:=igSymmetric, ExtrusionDistance:=0.1)
objBaseProfile.Visible = False
' *** creating a helix cutout feature
' creating a circular cross-section and a reference axis
Set objProfile = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(2))
Set objLine = objProfile.Lines2d.AddBy2Points(x1:=0, y1:=0.05, x2:=0, y2:=-0.05)
Set objRefAxis = objProfile.SetAxisOfRevolution(LineForAxis:=objLine)
Set objCrossSection = objProfile.Circles2d.AddByCenterRadius(x:=0.025, y:=-0.05, Radius:=0.01)
Set objCSArray(1) = objProfile
' creating the helix cutout feature and validating it
Set objHelixCutout = objDoc.Models(1).HelixCutouts.AddFinite(HelixAxis:=objRefAxis, _
AxisStart:=igEnd, NumCrossSections:=1, CrossSectionArray:=objCSArray, _
ProfileSide:=igRight, Height:=0.1, Pitch:=0.025, NumberOfTurns:=5, HelixDir:=igRight)
objProfile.Visible = False
If (objHelixCutout.Status <> igFeatureOK) Then
MsgBox "AddFinite method of the HelixCutouts object fails"
End If
' getting the parent object for the Helix Cutouts object
Set objHCParent = objDoc.Models(1).HelixCutouts.Parent
' USER DISPLAY
' Release objects
Set objApp = Nothing
Set objDoc = Nothing
Set objBaseProfile = Nothing
Set objBaseProfileArray(1) = Nothing
Set objBaseModel = Nothing
Set objProfile = Nothing
Set objLine = Nothing
Set objRefAxis = Nothing
Set objCrossSection = Nothing
Set objCSArray(1) = Nothing
Set objHelixCutout = Nothing
Set objHCParent = Nothing
End Sub