GetTerminator Method

Description

Returns the object to which the terminal end of a dimensioning or annotation object's leader connects.

Syntax

Visual Basic
Public Sub GetTerminator( _ ByRef TerminatorObj As Object, _ ByRef x As Double, _ ByRef y As Double, _ ByRef z As Double, _ ByRef keyPoint As Boolean _ )

Parameters

TerminatorObj: Specifies the object to which the terminal end of a dimensioning or annotation object's leader connects.
x: Coordinates of the leader's terminal connect point on the TerminatorObj.
y: Coordinates of the leader's terminal connect point on the TerminatorObj.
z: Coordinates of the leader's terminal connect point on the TerminatorObj.
keyPoint: Returns True if the leader was placed with respect to the TerminatorObj. Returns False if the leader was placed with respect to a key point on the TerminatorObj.

Remarks

This method also returns the coordinates of the leader's terminal connect point and a Boolean value to indicate whether the leader was placed with respect to the object or with respect to a key point on that object.

Example

Example (Visual Basic)

Private Sub Form_Load()
    Dim objApp As SolidEdgeFramework.Application
    Dim objDoc As SolidEdgeDraft.DraftDocument
    Dim objSheet As SolidEdgeDraft.Sheet
    Dim objLine As SolidEdgeFrameworkSupport.Line2d
    Dim objFCFs As SolidEdgeFrameworkSupport.FeatureControlFrames
    Dim objFCF As SolidEdgeFrameworkSupport.FeatureControlFrame
    Dim objTerminator As SolidEdgeFrameworkSupport.Line2d
    ' Local variables to be declared here
    Dim dblX As Double, dblY As Double, dblZ As Double
    Dim bKeyPoint As Boolean
    ' Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.DraftDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    On Error GoTo 0
    'Get the Active Sheet object
    Set objSheet = objDoc.ActiveSheet
    'Draw a line to be set as terminator object for the FeatureControlFrame
    Set objLine = objSheet.Lines2d.AddBy2Points(x1:=0.1, y1:=0.1, x2:=0.2, y2:=0.1)
    'Get the FeatureControlFrames collection object
    Set objFCFs = objSheet.FeatureControlFrames
    'Add a new FeatureControlFrame
    Set objFCF = objFCFs.AddByTerminator(TerminatorObject:=objLine, x:=0.125, y:=0.1, z:=0, Keypoint:=False)
    objFCF.PrimaryFrame = "FLVB0.001MCVBA"
    Call objFCF.AddVertex(x:=0.2, y:=0.2, z:=0)
    objFCF.BreakLine = True
    Call objFCF.GetTerminator(terminatorobj:=objTerminator, x:=dblX, y:=dblY, z:=dblZ, _
                              Keypoint:=bKeyPoint)
    ' Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objSheet = Nothing
    Set objLine = Nothing
    Set objFCFs = Nothing
    Set objFCF = Nothing
    Set objTerminator = Nothing
End Sub