Private Sub Form_Load()
    Dim objApp As SolidEdgeFrameWork.Application
    Dim objDoc As SolidEdgeDraft.DraftDocument
    Dim objSheet As SolidEdgeDraft.Sheet
    Dim objFCFs As SolidEdgeFrameworkSupport.FeatureControlFrames
    Dim objFCF As SolidEdgeFrameworkSupport.FeatureControlFrame
    ' Local variables to be declared here
    Dim dblVertices(5) As Double
    Dim lngVertexCount As Long
    ' Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.DraftDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    On Error GoTo 0
    'Get the Active Sheet object
    Set objSheet = objDoc.ActiveSheet
    'Get the FeatureControlFrames collection object
    Set objFCFs = objSheet.FeatureControlFrames
    'Add a new FeatureControlFrame
    Set objFCF = objFCFs.Add(x:=0.125, y:=0.1, z:=0)
    objFCF.PrimaryFrame = "FLVB0.001MCVBA"
    'Add few vertices to the FeatureControlFrame
    Call objFCF.AddVertex(x:=0.2, y:=0.2, z:=0)
    Call objFCF.AddVertex(0.25, 0.225, 0)
    objFCF.BreakLine = True
    dblVertices(0) = 0.1: dblVertices(1) = 0.1    'First vertex co-ords
    dblVertices(2) = 0.15: dblVertices(3) = 0.125    'Second vertex co-ords
    dblVertices(4) = 0.2: dblVertices(5) = 0.175    'Third vertex co-ords
    Call objFCF.SetVertices(VertexCount:=2, Vertices:=dblVertices)
    ' Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objSheet = Nothing
    Set objFCFs = Nothing
    Set objFCF = Nothing
End Sub