AddAsFillet Method

Description

Creates an Arc2d object that connects to two intersecting graphics objects.

Syntax

Visual Basic
Public Function AddAsFillet( _ ByVal Obj1 As Object, _ ByVal Obj2 As Object, _ ByVal Radius As Double, _ ByVal xDirection As Double, _ ByVal yDirection As Double _ ) As Arc2d

Parameters

Obj1: The first graphic object to which the fillet connects.
Obj2: The second graphic object to which the fillet connects.
Radius: Specifies the radius of the arc.
xDirection: Specifies the x value of the direction point in which to place the fillet. The direction point determines the direction in which the fillet will be placed relative to the intersection of the two objects.
yDirection: Specifies the y value of the direction point in which to place the fillet. The direction point determines the direction in which the fillet will be placed relative to the intersection of the two objects.

Remarks

A fillet arc will have end point and tangent relations to the two objects and the two objects will be trimmed to the intersection of the fillet arc. The fillet is placed between 2 objects. The direction point determines the direction to place the fillet relative to the intersection of the 2 objects. If two lines are drawn to form an “X”, there are 4 possible directions at which the fillet can be placed. This is because there are 4 areas from the intersection of the lines at which a fillet can be constructed. The radius determines the radius of the fillet. The objects will be trimmed if they are open objects such as lines and arcs. If the objects are closed objects such as circles and ellipses, they will not be trimmed. The following illustrates an Arc2d object added as a fillet.

Example

Example (Visual Basic)

Private Sub Form_Load()
    Dim objApp As SolidEdgeFramework.Application
    Dim objDoc As SolidEdgePart.PartDocument
    Dim objArcs As SolidEdgeFrameworkSupport.Arcs2d
    Dim objL1 As SolidEdgeFrameworkSupport.Line2d
    Dim objL2 As SolidEdgeFrameworkSupport.Line2d
    Dim sDumpStatus As String    ' Used for temporary storage of datadump return string
    ' Report errors
    Const PI = 3.14159265358979
    ' Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.PartDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    ' Create an Arcs collection object
    Set objArcs = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(1)).Arcs2d
    ' Create two intersecting line objects
    Set objL1 = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(1)). _
                Lines2d.AddBy2Points(x1:=0, y1:=0, x2:=0.1, y2:=0)
    Set objL2 = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(1)). _
                Lines2d.AddBy2Points(x1:=0, y1:=0.1, x2:=0, y2:=0)
    ' Create an arc object
    Call objArcs.AddAsFillet(Obj1:=objL1, Obj2:=objL2, Radius:=0.05, _
                             xDirection:=0.15, yDirection:=0.05)
    ' USER DISPLAY
    ' Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objArcs = Nothing
    Set objL1 = Nothing
    Set objL2 = Nothing
End Sub