Duplicate Method

Description

Copies the referenced object to a specified location, creating a new instance of the object with the same property values as the original.

Syntax

Visual Basic
Public Function Duplicate( _ Optional ByVal XDistance As Variant, _ Optional ByVal YDistance As Variant _ ) As Object

Parameters

XDistance: Specifies the distance in the x direction from the original that the copy of the referenced object is to be placed.
YDistance: Specifies the distance in the y direction from the original that the copy of the referenced object is to be placed.

Remarks

The referenced object is copied to the new location relative to the original (source) location. The distance is the difference from the object's original location to the XDistance and YDistance values. The new object is returned.

Example

Example (Visual Basic)

Private Sub Form_Load()
    Dim objApp As SolidEdgeFrameWork.Application
    Dim objDoc As SolidEdgeDraft.DraftDocument
    Dim objSheet As SolidEdgeDraft.Sheet
    Dim objCompStrns As SolidEdgeFrameworkSupport.ComplexStrings2d
    Dim objCompStrn1 As SolidEdgeFrameworkSupport.ComplexString2d
    Dim objL1 As SolidEdgeFrameworkSupport.Line2d
    Dim objL2 As SolidEdgeFrameworkSupport.Line2d
    Dim objL3 As SolidEdgeFrameworkSupport.Line2d
    Dim objBObjs(0 To 2) As Object
    ' Report errors
    Const PI = 3.14159265358979
    ' Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.DraftDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    On Error GoTo 0
    'Get the Active Sheet object
    Set objSheet = objDoc.ActiveSheet
    'Create ComplexStrings2d collection object
    Set objCompStrns = objSheet.ComplexStrings2d
    'Draw few lines on the active sheet
    Set objL1 = objSheet.Lines2d.AddBy2Points(x1:=0.1, y1:=0.1, x2:=0.2, y2:=0.2)
    Set objL2 = objSheet.Lines2d.AddBy2Points(x1:=0.2, y1:=0.2, x2:=0.4, y2:=0.2)
    Set objL3 = objSheet.Lines2d.AddBy2Points(x1:=0.4, y1:=0.2, x2:=0.5, y2:=0.1)
    'Store the Objects in an Array
    Set objBObjs(0) = objL1
    Set objBObjs(1) = objL2
    Set objBObjs(2) = objL3
    'Create the ComplexString2d
    Set objCompStrn1 = objCompStrns.AddByObjects(ArraySize:=3, Members:=objBObjs())
    'Create Copy of the ComplexString2d at a specified distance
    Call objCompStrn1.Duplicate(xDistance:=0.075, yDistance:=0.125)
    ' USER DISPLAY
    ' Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objSheet = Nothing
    Set objCompStrns = Nothing
    Set objCompStrn1 = Nothing
    Set objL1 = Nothing
    Set objL2 = Nothing
    Set objL3 = Nothing
    Set objBObjs(0) = Nothing
    Set objBObjs(1) = Nothing
    Set objBObjs(2) = Nothing
End Sub