AddChamfer Method

Description

Creates a chamfer relationship between a Line2d object and the two objects it intersects.

Syntax

Visual Basic
Public Function AddChamfer( _ ByVal Object1 As Object, _ ByVal Index1 As Long, _ ByVal Line As Object, _ ByVal line_index As Long, _ ByVal Object2 As Object, _ ByVal Index2 As Long, _ Optional ByVal guaranteed_ok As Variant _ ) As Relation2d

Visual Basic

Public Function AddChamfer( _
   ByVal Object1 As Object, _
   ByVal Index1 As Long, _
   ByVal Line As Object, _
   ByVal line_index As Long, _
   ByVal Object2 As Object, _
   ByVal Index2 As Long, _
   Optional ByVal guaranteed_ok As Variant _
) As Relation2d

Parameters

Object1: Specifies the object whose intersection with the Line2d object forms the start of the chamfer.
Index1: Specifies the index of the first object (Object1).
Line: Specifies the Line2d object for which the chamfer relationship is being established.
line_index: Specifies the index of the Line2d object.
Object2: Specifies the object whose intersection with the Line2d object forms the end of the chamfer.
Index2: Specifies the index of the second object (Object2).
guaranteed_ok: If guaranteed_ok is True, checking is performed to ensure that the relationship does not contradict previously placed relationships.

Remarks

As a result of this method, all geometry that exceeds the points of intersection is trimmed. Relationship Add methods have checks to ensure that a new relationship does not contradict previously placed relationships. For example, AddHorizontal will return an error if the line already has a vertical relationship. This check can be turned off to enhance performance. The optional guaranteed_ok argument, if set to 1, bypasses relationship checking. However, this feature could leave the system in an unsolvable state, so use it carefully. It is best to use this feature only on a new element with no other relationships.

Example

Example (Visual Basic)

Private Sub Form_Load()
    Dim objApp As SolidEdgeFramework.Application
    Dim objDoc As SolidEdgePart.PartDocument
    Dim objLine1 As SolidEdgeFrameworkSupport.Line2d
    Dim objLine2 As SolidEdgeFrameworkSupport.Line2d
    Dim objLine3 As SolidEdgeFrameworkSupport.Line2d
    Dim objRelns As SolidEdgeFrameworkSupport.Relations2d
    Dim objReln1 As SolidEdgeFrameworkSupport.Relation2d
    Dim objProfile As SolidEdgePart.Profile
    ' Report errors
    Const PI = 3.14159265358979
    ' Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.PartDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    ' Create an empty Profile
    Set objProfile = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:= _
                                                         objDoc.RefPlanes(1))
    ' Create 3 Line objects
    Set objLine1 = objProfile.Lines2d.AddBy2Points(x1:=0.01, y1:=0.01, x2:=0.01, y2:=0.05)
    Set objLine2 = objProfile.Lines2d.AddBy2Points(x1:=0, y1:=0.04, x2:=0.075, y2:=0.075)
    Set objLine3 = objProfile.Lines2d.AddBy2Points(x1:=0.05, y1:=0.06, x2:=0.1, y2:=0.06)


    ' Create a Chamfer Relation between the objects
    Set objRelns = objProfile.Relations2d
    Set objReln1 = objRelns.AddChamfer(Object1:=objLine1, Index1:=igLineEnd, Line:=objLine2, _
                                       line_index:=igLineStart, Object2:=objLine3, Index2:=igLineStart)

    ' USER DISPLAY
    ' Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objLine1 = Nothing
    Set objLine2 = Nothing
    Set objLine3 = Nothing
    Set objRelns = Nothing
    Set objReln1 = Nothing
    Set objProfile = Nothing
End Sub